*                                                                     
* Access storage in a Dataspace                                       
*                                                                     
* Input: R1 has buffer location for returned storage                  
*        R0 has length to get                                         
*        R15 has starting address in the Dataspace                    
*        GDS_DSPName has 8 character Dataspace name               
*        GDS_ASID    has 2 byte ASID                              
*                                                                     
Get_Dataspace_Storage DS 0H                                       
         BAKR  R14,0                                                  
         LR    R6,R15                   Save address in DS            
         LR    R7,R0                    Save length to get            
*                                                                     
         LA    R14,GDS_ESSY             To: Address                   
         L     R15,=AL4(C_ESSYL)        To: Length                    
         LA    R4,C_ESSY                From: Address                 
         LR    R5,R15                   From: Length                  
         MVCL  R14,R4                   Zero out area                 
*                                                                     
         MVC   GDS_ESSYSYM(8),GDS_DSPName                         
         MVC   GDS_ESSYAST,=AL2(ZZZASTDS) ASID DSPNAME                
         LH    R0,GDS_ASID          Get ASID                      
         ST    R0,GDS_ESSYAS1                                         
         MVC   GDS_ESSYAS2(8),GDS_DSPName                         
         ST    R6,GDS_ESSYLAD                                         
         MVC   GDS_ESSYDTY,=AL1(ZZZDTYU) Area (already default)       
         MVC   GDS_ESSYDTD(8),GDS_DSPName                         
         ST    R7,GDS_ESSYDLE           Set length to get             
*                                                                     
         L     R2,X_ABDPL              Locate ABDPL                  
         USING ABDPL,R2                                               
*                                                                     
         LA    R3,GDS_XSSP                                            
         MVC   0(C_XSSPL,R3),C_XSSP                                   
         MVC   GDS_XSSPCODE,=AL2(GDS_XSSPACC) Function: Access Storage
         MVC   GDS_XSSPMODN,5(R12)      Program name from eycatcher   
         ST    R1,GDS_XSSPBUF                                         
         LA    R4,GDS_ESSY              Locate ESR                    
         ST    R4,GDS_XSSPESR           Set Equate Symbol record
         
         L     R15,ADPLSERV-ABDPL(R2)   Locate IPCS service routine     
         CALL  (15),((2),                 Call IPCS Service routine    @
               =AL4(ADPLSSYM),            ..Symbol Service             @
               (3)),                      ..XSSP                       @
               MF=(E,PWAPARM)                                           
         PR    ,                                                        
         DROP  R2        
...
C_ESSY   BLSRESSY DSECT=NO   
C_ESSYL  EQU    *-C_ESSY
...
GDS_ESSY    BLSRESSY DSECT=NO 
GDS_XSSP    BLSRXSSP DSECT=NO
GDS_PACC    ds    XL(ADPLLACC) 
*
GDS_DSPNAME DS    CL8        Dataspace Name
GDS_ASID    DS    XL2        ASID