* Name:    SAMPEC
* Purpose: Quick and dirty code to show standard OS Eyecatchers
* Logic:   CSECTA (main csect) calls
*          -> CSECTB which calls
*             -> CSECTC which calls
*                -> CSECTD which ABENDs
*-------------------------------------------------------------------
         YREGS ,                        Equate registers
CSECTA   CSECT ,
*
** Standard O/S Eyecatcher
*
A_EC     B    A_ECL(0,R15)              Branch past Eyecatcher
         DC   AL1(A_ECE-A_ECV)          Length of Eyecatcher
A_ECV    DC   C'CSECTA - &SYSDATC &SYSTIME - '
         DC   C'Main CSECT in SAMPEC: Calls CSECTB'
A_ECE    EQU  *
         DS   0H
A_ECL    EQU  *-A_EC
         SPACE 2
*-Entry Housekeeping
         STM   R14,R12,12(R13)
         LR    R12,R15
         USING CSECTA,R12
         LA    R1,ARSA
         ST    R1,8(,R13)
         ST    R13,4(,R1)
         LR    R13,R1
         L     R1,4(,R1)
         L     R1,24(,R1)
*- Call CSECTB
         L     R15,=V(CSECTB)
         BALR  R14,R15
*-Normally Exit housekeeping would be here
         LTORG ,
ARSA     DS    18F
         DROP  R12
*-----------------------------------------------------------------
CSECTB   CSECT ,
*
** Standard O/S Eyecatcher
*
B_EC     B    B_ECL(0,R15)              Branch past Eyecatcher
         DC   AL1(B_ECE-B_ECV)          Length of Eyecatcher
B_ECV    DC   C'CSECTB - &SYSDATC &SYSTIME - '
         DC   C'Calls CSECTC which has no eyecatcher'
B_ECE    EQU  *
         DS   0H
B_ECL    EQU  *-B_EC
         SPACE 2
*-Entry Housekeeping
         STM   R14,R12,12(R13)
         LR    R12,R15
         USING CSECTB,R12
         LA    R1,BRSA
         ST    R1,8(,R13)
         ST    R13,4(,R1)
         LR    R13,R1
         L     R1,4(,R1)
         L     R1,24(,R1)
*- Call CSECTC
         L     R15,=V(CSECTC)
         BALR  R14,R15
*-Normally Exit housekeeping would be here
         LTORG ,
BRSA     DS    18F
         DROP  R12
*-----------------------------------------------------------------
CSECTC   CSECT ,
*-Show what happens if NO eyecatcher
*-Entry Housekeeping
         STM   R14,R12,12(R13)
         LR    R12,R15
         USING CSECTC,R12
         LA    R1,CRSA
         ST    R1,8(,R13)
         ST    R13,4(,R1)
         LR    R13,R1
         L     R1,4(,R1)
         L     R1,24(,R1)
*- Call CSECTD
         L     R15,=V(CSECTD)
         BALR  R14,R15
*-Normally Exit housekeeping would be here
         LTORG ,
CRSA     DS    18F
         DROP  R12
*-----------------------------------------------------------------
CSECTD   CSECT ,
*
** Standard O/S Eyecatcher
*
D_EC     B    D_ECL(0,R15)              Branch past Eyecatcher
         DC   AL1(D_ECE-D_ECV)          Length of Eyecatcher
D_ECV    DC   C'CSECTD - &SYSDATC &SYSTIME - '
         DC   C'We ABEND to show Save Area Trace'
D_ECE    EQU  *
         DS   0H
D_ECL    EQU  *-D_EC
         SPACE 2
*-Entry Housekeeping
         STM   R14,R12,12(R13)
         LR    R12,R15
         USING CSECTD,R12
         LA    R1,DRSA
         ST    R1,8(,R13)
         ST    R13,4(,R1)
         LR    R13,R1
         L     R1,4(,R1)
         L     R1,24(,R1)
*-ABEND so we can see the entries in the SYSUDUMP Save Area Trace
         DC    A(0)                     Cause S0C1 ABEND
*-Normally Exit housekeeping would be here
         LTORG ,
DRSA     DS    18F
         DROP  R12
         END ,