DA$MPF05 TITLE 'Suppress WTO on the JES2 JOB LOG'
***********************************************************************
***                                                                 ***
**                                                                   **
**    Module Name       = DA$MPF05                                   **
**                                                                   **
**    Descriptive Name  = Suppress WTO from JES2 JOB LOG             **
**                                                                   **
**                        The message will still go to the SYSLOG.   **
**                                                                   **
**                        ** You must be at JES2 3.1.3 or higher **  **
**                                                                   **
**    Reference         = GC28-1147 MVS-XA SPL: User Exits           **
**                                                                   **
**    Activated by      = Specifed in active MPF member of Parmlib:  **
**                        - SET MPF=XX                               **
**                        - Where XX is a member in SYS1.PARMLIB as  **
**                          in 'SYS1.PARMLIB(MPFLSTXX)'              **
**                        - Reference IN MPFLSTXX:                   **
**                       DA$106I,SUP(NO),USEREXIT(DA$MPF05)          **
**                       DA$107I,SUP(NO),USEREXIT(DA$MPF05)          **
**                                                                   **
***                                                                 ***
***********************************************************************
         EJECT
DA$MPF05 CSECT ,
DA$MPF05 AMODE 31
DA$MPF05 RMODE ANY
*
** Entry Housekeeping
*
         SAVE  (14,12),,DA$MPF05_WTOEXIT_SUPJESLOG_&SYSDATE._&SYSTIME
         LR    R12,R15                    Load Base register
         USING DA$MPF05,R12               Get CSECT addressability
         L     R2,0(R1)                   Get CTXT Address
*
** Check for any exceptions
*
         CLC   CTXTJBNM-CTXT(8,R2),=CL8'IBMUSERZ' Special job?
         BE    EXIT                       Yes, skip suppression
*
** Set flag to suppress the message from the JES JOB Log
*
         OI    CTXTERF3-CTXT(R2),CTXTESJL Suppress that puppy
*
** Exit Housekeeping
*
EXIT     EQU   *
         RETURN (14,12),RC=0              Return to caller
*
** Literals and DSECTs
*
         LTORG ,                          Literals used in DA$MPF05
         DS    0D                         End of DA$MPF05 WTO exit
         YREGS ,                          Generate register equates
         IEZVX100 ,                       Commun. Task User exit parms
         END   ,